PutOnUserDesktop(UserList As Variant,NMkIdList As Variant,Comment As String,Caption As String) As Boolean

PutOnUserDesktop(UserList As Variant,NMkIdList As Variant,Comment As String,Caption As String) As Boolean ( PropertyGet )

Поместить на рабочий стол

Синтаксис:

objectvariable.PutOnUserDesktop( UserList, NMkIdList, Comment, Caption )

objectvariable - ITcs_Application

UserList - массив идентификаторов пользователей (не больше 1000), если Null - то можно выбрать

NMkIdList - массив идентификаторов номенклатуры

Comment - текст комментария (пустая-задается пользователем)

Caption - заголовок

Возвращает: логическое значение - признак успешного завершения операции

Пример на VB:

Dim TcsObj As CSDN.TCS
Dim App As CSDN.Tcs_Application
Dim Users As CSDN.Users
Dim NMks As CSDN.Nomenclatures
Dim UserList() As Long
Dim NMkIdList() As Long
Dim cn As Integer
Set TcsObj = CreateObject("CSDN.TCS")
Set App = TcsObj.Login
If App.NmkClasses.RunModuleForSelect("Выберите класс", False) Then
    Set NMks = App.Nomenclatures(App.NmkClasses.Properties("ID").AsInteger)
    
    If NMks.RunModuleForSelect("Выберите номенклатуру", True) Then
            
        ReDim NMkIdList(NMks.SelectedRowsCount - 1)
        For cn = 0 To NMks.SelectedRowsCount - 1
            If NMks.GotoSelectedRow(cn) Then
                NMkIdList(cn) = NMks.Properties("ID").AsInteger
            Else
                'выбранная запись не считалась
                'запишем 0, так как он игнорируется
                NMkIdList(cn) = 0
            End If
        Next
        Set Users = App.Users
        If Users.RunModuleForSelect("Выберите пользователей", True) Then
            
            ReDim UserList(Users.SelectedRowsCount - 1)
            For cn = 0 To Users.SelectedRowsCount - 1
                If Users.GotoSelectedRow(cn) Then
                    UserList(cn) = Users.Properties("ID").AsInteger
                Else
                    'выбранная запись не считалась
                    'запишем 0, так как он игнорируется
                    UserList(cn) = 0
                End If
            Next
            
            If App.PutOnUserDesktop(UserList, NMkIdList, "Задание на проектирование", "Поместить на рабочий стол") Then
                MsgBox "Операция выполнена."
            Else
                MsgBox "Операция не выполнена."
            End If
            
        End If
            
        Set Users = Nothing
        
    End If
    Set NMks = Nothing
End If
Set App = Nothing
Set TcsObj = Nothing